[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
20030920: Looking for NLDN scripts (cont.)

Subject: 20030920: Looking for NLDN scripts (cont.)
Date: Mon, 22 Sep 2003 10:16:48 -0600
>From: Chris Novy <address@hidden>
>Organization: SIU
>Keywords: 200309210401.h8L41jk1028746 GEMPAK scripts NLDN lightning

Hi Chris,

>From address@hidden Sun Sep 21 11:04:24 2003

re: restriction on NLDN lightning

>It's already set up that way.  I have a restriction to the SIU.EDU domain 
>set up in the .nsconfig file.  I had been generating the NLDN images a 
>while back using McIDAS OS/2 but that machine died.  I want to get the 
>images back using GEMPAK.   The weather site at SIU is a very low priority 
>for me but one I still like to deal with.  My main use of the IDD data 
>stream is to feed the WX-***** e-mail lists for storms and tropical weather 
>interests.

>Thanks for the reminder all the same.

I just wanted to make sure that inquiries that get into the tracking
system are very clear to the uninformed reader that NLDN lightning data
is restricted.

>I'm new to this list but not to the UNIDATA community.  I'm recently 
>installed GEMPAK at SIU and would like to know if anyone has some sample 
>scripts for generating NLDN GIF (non-Xwindows) graphics.  I've got the NLDN 
>decoder generating the .gem files but I don't know how to display 
>them.  I'm interested in reverse-engineering someone else's scripts. These 
>images will appear on the weather.siu.edu web site.

Jeff Weber provided a couple of GEMPAK scripts to me to pass along to you.
His comments are:

"Both of these overlay the nat'l radar mosaic w/the lightning."

---------------------- lightning.csh - begin --------------------------------

#!/bin/csh -f

source /home/gempak/Gemenviron

set WORKDIR=/radar/lightningwork.$$
mkdir $WORKDIR

# change WEBDIR accordingly
set WEBDIR=/radar/lightning_gifs
if(! -e $WEBDIR) mkdir $WEBDIR

set RADDIR=$SAT/NEXRCOMP/1km/n0r

set STIMES=`sfctime NLDN | tail -10`

foreach STIME ($STIMES)
   set YYYYMMDD_HHNN=`echo 20${STIME} | tr '/' '_'`
   setenv TCOPY $YYYYMMDD_HHNN
   if(-e ${WEBDIR}/${YYYYMMDD_HHNN}_lightning.gif) then
      continue
   endif

   echo need $STIME


   cd $RADDIR

   set TEST=n0r_${YYYYMMDD_HHNN}

   if(-e $TEST ) then
      set IFILE=$TEST
   else

      ls n0r_* >! /radar/lightning_srch.$$
      echo $TEST >>! /radar/lightning_srch.$$
   
      set MFILES=`sort /radar/lightning_srch.$$`
      rm -f /radar/lightning_srch.$$

      set LCNT=2
      @ CNT = 1
      while(($CNT < $#MFILES)&&($MFILES[$CNT] != $TEST))
          set LCNT = $CNT
          @ CNT = $CNT + 1
      end
      set IFILE=$MFILES[$LCNT]
   endif
   #print 'got here'

   cd $WORKDIR

   set TITLE="Base Reflectivity and Lightning Location ~"

   set GIFFILE=${YYYYMMDD_HHNN}_lightning.gif
   set DEVICE="gif|${GIFFILE}|1200;750"

   sfmap << EOF
    \$respond = yes
    AREA     = dset
    GAREA    = 20;-125;45;-60
    SATFIL   = \$SAT/NEXRCOMP/1km/n0r/${IFILE}
    RADFIL   = 
    SFPARM   = points
    DATTIM   = ${STIME}
    SFFILE   = NLDN
    COLORS   = 
    MAP      = 18/1/1
    LATLON   = 0
    TITLE    = 3/-6/${TITLE}
    CLEAR    = y
    PANEL    = 0
    DEVICE   = ${DEVICE}
    PROJ     = sat
    FILTER   = 
    TEXT     = 1/2/hw
    LUTFIL   = default
    STNPLT   =  
    CLRBAR   = 6|1/1/2
    IMBAR    = 2
    r

    e
EOF

#   echo "N0R" >! bar_label.txt
#   echo "location" >>! bar_label.txt

#   gptext << EOF1
#    PANEL    = 0
#    COLORS   = 6
#    TEXT     = 1/1/2
#    CLEAR    = n
#    DEVICE   = ${DEVICE}
#    TXTFIL   = bar_label.txt
#    TXTLOC   = .007;.58
#    COLUMN   = 1
#    r
# 
#    e
#EOF1

   gpend
#   rm bar_label.txt
   ls
   if(-e $GIFFILE) mv $GIFFILE $WEBDIR

end

rm *.nts
cd ..
rmdir $WORKDIR

cd $WEBDIR

set FILES=`ls lightningloop*`
if($#FILES > 0) rm -f lightningloop*

#set FILES=`ls [0-2]*_lightning.gif | tail -9`
#for new longer loop
set FILES=`ls [0-2]*_lightning.gif | tail -29`

@ CNT = 0
foreach FILE ($FILES)
   ln -s $FILE lightningloop${CNT}
   @ CNT = $CNT + 1
end


# lets scour older gifs
#changed from 20-40
@ KEEP = 40
#changed [0-2] to [0-4]
set FILES=`ls -r [0-2]*_lightning.gif`

if( $#FILES <= $KEEP ) exit

@ CNT = $KEEP + 1
echo look $KEEP $#FILES $CNT
while ( $CNT <= $#FILES )
   echo scouring $FILES[${CNT}]
   rm -f $FILES[${CNT}]
   @ CNT = $CNT + 1
end

---------------------- lightning.csh - end ----------------------------------

---------------------- lightning_white.csh - begin --------------------------

#!/bin/csh -f

source /home/gempak/Gemenviron

set WORKDIR=/radar2/lightningwork.$$
mkdir $WORKDIR

# change WEBDIR accordingly
set WEBDIR=/radar2/lightning_gifs
if(! -e $WEBDIR) mkdir $WEBDIR

set RADDIR=$SAT/NEXRCOMP/1km/n0r

set STIMES=`sfctime NLDN | tail -10`

foreach STIME ($STIMES)
   set YYYYMMDD_HHNN=`echo 20${STIME} | tr '/' '_'`
   setenv TCOPY $YYYYMMDD_HHNN
   if(-e ${WEBDIR}/${YYYYMMDD_HHNN}_lightning.gif) then
      continue
   endif

   echo need $STIME


   cd $RADDIR

   set TEST=n0r_${YYYYMMDD_HHNN}

   if(-e $TEST ) then
      set IFILE=$TEST
   else

      ls n0r_* >! /radar2/lightning_srch.$$
      echo $TEST >>! /radar2/lightning_srch.$$
   
      set MFILES=`sort /radar2/lightning_srch.$$`
      rm -f /radar2/lightning_srch.$$

      set LCNT=2
      @ CNT = 1
      while(($CNT < $#MFILES)&&($MFILES[$CNT] != $TEST))
          set LCNT = $CNT
          @ CNT = $CNT + 1
      end
      set IFILE=$MFILES[$LCNT]
   endif
   #print 'got here'

   cd $WORKDIR

   set TITLE="Base Reflectivity and Lightning Location ~"

   set GIFFILE=${YYYYMMDD_HHNN}_lightning.gif
   set DEVICE="gif|${GIFFILE}|1200;750"

   sfmap << EOF
    \$respond = yes
    \$mapfil = base + rdis.uni
    AREA     = dset
    GAREA    = 20;-125;45;-60
    SATFIL   = \$SAT/NEXRCOMP/1km/n0r/${IFILE}
    RADFIL   = 
    SFPARM   = location
    DATTIM   = ${STIME}
    SFFILE   = NLDN
    COLORS   = 31
    MAP      = 18/1/1 + 23/1/1
    LATLON   = 0
    TITLE    = 3/-6/${TITLE}
    CLEAR    = y
    PANEL    = 0
    DEVICE   = ${DEVICE}
    PROJ     = sat
    FILTER   = 
    TEXT     = 1/2/hw
    LUTFIL   = default
    STNPLT   =  
    CLRBAR   = 6|1/1/2
    IMBAR    = 2
    r

    e
EOF

#   echo "N0R" >! bar_label.txt
#   echo "location" >>! bar_label.txt

#   gptext << EOF1
#    PANEL    = 0
#    COLORS   = 6
#    TEXT     = 1/1/2
#    CLEAR    = n
#    DEVICE   = ${DEVICE}
#    TXTFIL   = bar_label.txt
#    TXTLOC   = .007;.58
#    COLUMN   = 1
#    r
# 
#    e
#EOF1

   gpend
#   rm bar_label.txt
   ls
   if(-e $GIFFILE) mv $GIFFILE $WEBDIR

end

rm *.nts
cd ..
rmdir $WORKDIR

cd $WEBDIR

set FILES=`ls lightningloop*`
if($#FILES > 0) rm -f lightningloop*

#set FILES=`ls [0-2]*_lightning.gif | tail -9`
#for new longer loop
set FILES=`ls [0-2]*_lightning.gif | tail -29`

@ CNT = 0
foreach FILE ($FILES)
   ln -s $FILE lightningloop${CNT}
   @ CNT = $CNT + 1
end


# lets scour older gifs
#changed from 20-40
@ KEEP = 40
#changed [0-2] to [0-4]
set FILES=`ls -r [0-2]*_lightning.gif`

if( $#FILES <= $KEEP ) exit

@ CNT = $KEEP + 1
echo look $KEEP $#FILES $CNT
while ( $CNT <= $#FILES )
   echo scouring $FILES[${CNT}]
   rm -f $FILES[${CNT}]
   @ CNT = $CNT + 1
end

---------------------- lightning_white.csh - end ----------------------------

>Thanks in advance.

No worries.

Tom
Prev by Date: 20030920: Looking for NLDN scripts
Next by Date: 20030919: 20030918: GEMPAK and pseudo-color on Linux
Previous by thread: 20030920: Looking for NLDN scripts
Next by thread: 20030919: 20030918: GEMPAK and pseudo-color on Linux
Index(es):
- Date
- Thread